/CLEAR,NOSTART

! Ouverture du post traitement
/PREP7 

!----------------------!
!- Creation manivelle -!
!----------------------!

! Creation de points
K,1,0,0,0, 
K,2,17,0,0,
K,3,170,0,0, 
K,4,184,0,0,

! Creation de cercle
CIRCLE, 1, , , 2, ,
CIRCLE, 3, , , 4, ,

! Creation de lignes
LSTR,       6,      10 
LSTR,       8,      12

! Creation de surface par contour
AL,2,3,10,8,5,9

! Creation de volume par extrusion
VEXT,1, , ,0,0,10,,,,

! Percage pied
K,33,170,0,20, 
K,34,177,0,20,
CIRCLE, 33, , , 34, ,
AL,23,24,25,26
VEXT,9, , ,0,0,-30,,,,

! Percage tete
K,43,0,0,20, 
K,44,10,0,20,
CIRCLE, 43, , , 44, ,
AL,35,36,37,38
VEXT,15, , ,0,0,-30,,,,

! Creation trou de l axe par soustraction
VSBV,1,2,,,
VSBV,4,3,,,

!----------------------------------!
!- Parametres modelisation solide -!
!----------------------------------!

! Elt volume  
ET,1,SOLID185

! Materiau
MPTEMP,,,,,,,,  
MPTEMP,1,0  
MPDATA,EX,1,,2e11   
MPDATA,PRXY,1,,0.3  

!----------------------!
!- Ajout de la pédale -!
!----------------------!

! KP centre pedale
N,1,170,0,50,
N,2,170,0,35,

! Element poutre
ET,10,BEAM188
  
! Section tige
SECTYPE,10, BEAM, CSOLID, tige, 0 
SECOFFSET, CENT 
SECDATA,7,0,0,0,0,0,0,0,0,0,0,0 

! Attribut maillage
TYPE,10   
MAT,1
REAL,   
ESYS,0   
SECNUM,10 
TSHAP,LINE

! Creation elt
E,1,2

!-----------------------------!
!- Maillage solide et pedale -!
!-----------------------------!

! Maillage
VATT,1,,1,0   
ESIZE,3,0,
MSHKEY,0
MSHAPE,1,3d
VMESH,ALL

! Creation liaison rigide
ASEL,S,,,21,24,1
NSLA,R,1
NSEL,A,,,1
CERIG,1,ALL,ALL,,,,

NSEL,S,,,ALL
ASEL,S,,,ALL

!--------------------------!
!- Conditions aux limites -!
!--------------------------!
ASEL,S,,,1,2,1
ASEL,A,,,9,10,1
DA,ALL,ALL,0 
ASEL,S,,,ALL

F,1,FY,-100*9.81*1.2