!-----------------------------------!
! Etude d'un portique !
!-----------------------------------!

/CLEAR,NOSTART

/FILNAME,tp3,0 

/PREP7  

! creation des points
!--------------------
K,1,0,-5000,0,  
K,2,5000,-5000,0, 
K,3,5000,5000,0,
K,4,0,5000,0,
K,5,0,-5000,2000,  
K,6,5000,-5000,2000, 
K,7,5000,5000,2000,
K,8,0,5000,2000,
K,9,5000,0,2000

! creation des lignes
!--------------------
LSTR,1,5  
LSTR,2,6
LSTR,3,7
LSTR,4,8
LSTR,5,6
LSTR,6,9
LSTR,9,7
LSTR,7,8
LSTR,8,5

! orientation des lignes
!-----------------------
/PSYMB,LDIR,1

LPLOT

! selection du type d element
!----------------------------
ET,1,BEAM188

! Acier
!------
MPTEMP,,,,,,,,  
MPTEMP,1,0  
MPDATA,EX,1,,2e5
MPDATA,PRXY,1,,0.3
MPDATA,DENS,1,,7800e-9

! section en I
!-------------
SECTYPE,   1, BEAM, I, secI, 0  
SECOFFSET, CENT 
SECDATA,55,55,100,5.7,5.7,4.1,0,0,0,0,0,0

! section en L
!-------------
SECTYPE,   2, BEAM, L, secL, 0  
SECOFFSET, CENT 
SECDATA,55,55,6,6,0,0,0,0,0,0,0,0

! attributs du maillage
!----------------------
seL=2
seI=1
LSEL,S,,,1
LATT,1,,1,,4,,seL  
LSEL,S,,,2
LATT,1,,1,,1,,seL
LSEL,S,,,3
LATT,1,,1,,2,,seL
LSEL,S,,,4
LATT,1,,1,,3,,seL

LSEL,S,,,5
LATT,1,,1,,2,,seI
LSEL,S,,,6
LATT,1,,1,,2,,seI
LSEL,S,,,7
LATT,1,,1,,2,,seI
LSEL,S,,,8
LATT,1,,1,,4,,seI
LSEL,S,,,9
LATT,1,,1,,4,,seI


! taille des elements
!--------------------
LSEL,S,,,1,9,1
LESIZE,ALL,200, , , , , , ,1

! maillage
!---------
LSEL,S,,,1,9,1
LMESH,ALL

! orientation des elements
!-------------------------
/PSYMB,LDIR,0
/PSYMB,ESYS,1   

/ESHAPE,1.0

EPLOT

! calcul statique
!----------------
/SOL

ANTYPE,0

! deplacements imposes
!---------------------
KSEL,S,,,1,4,1   
DK,ALL, ,0, ,0,ALL, , , , , ,

! force ponctuelle
!-----------------
FK,9,FZ,-2000

! force lineique
!---------------
ESEL,S,,,141,190,1
SFBEAM,ALL,1,PRES,-0.1, , , , , ,0  
SFBEAM,ALL,2,PRES,0.1, , , , , ,0  

ALLSEL,ALL  

! resolution
!-----------
SOLVE   

! affichage de la deformee
!-------------------------
/POST1  

PLDISP,1

! table des efforts normaux
!--------------------------
ETABLE,sdir,SMISC, 31   
 
PLETAB,SDIR,NOAV